HP OpenVMS Systems Documentation

DECnet Phase V end systems can operate over more than one data link. As such, traffic can be sent or received over any of the links, but protocol data units (PDUs) are not forwarded from one link to another. In other words, a multicircuit end system does not perform the functions of a router. Instead, this function provides network redundancy, as well as higher throughput, depending upon the configuration.

DECnet-Plus for OpenVMS supports up to 16 circuits. Hardware, OpenVMS, or WANDD software, however, can further limit the number of circuits you can have. For more information about possible limits, refer to your system and WANDD documentation.

When communicating with remote systems, data PDUs are sent over all circuits in turn. If the remote end system is directly connected on one or more circuits, only those circuits are used to reach the end system. Moreover, a single data PDU is transmitted over all circuits at the interval at which you set the probe rate.

The probe rateis a Routing module attribute that has a default value of 1000 on OpenVMS systems. Therefore, every thousandth data PDU bound for a specific end system is transmitted on all circuits. This helps ensure that all available paths are used.

When operating a DECnet-Plus end system in a multicircuit configuration, you must adhere to certain topology restrictions:

• All the links must be in the same area. That is, the set of area addresses (a Routing module status attribute) must be the same for each circuit.
• All the data links must be of similar capacity or usable bandwidth.
• If an end system has multiple circuits connected to an extended LAN, only one of those circuits can have the attribute Enable Phase IV Address set to True.

Failure to comply with these restrictions might result in unacceptable operation.

To create multiple circuits for an end system on a CSMA-CD LAN, use your DECnet-Plus configuration procedure. DIGITAL recommends that you accept the default settings (used in the example in Section 8.4.2.2) for the various attributes and change these only if you need to. Refer to the DECnet-Plus Network Control Language Reference for more information about these attributes.

8.4.2.2 Sample NCL Script for Configuring Multiple Routing Circuits

The following example shows the contents of the file NET$ROUTING_STARTUP.NCL, located by default in SYS$SPECIFIC:[SYSMGR]. This file is created by the DECnet-Plus for OpenVMS configuration procedure. The file enables routing, creates the Routing module, and creates CSMA-CD and FDDI circuits.

create node 0 routing type endnode
set node 0 routing phaseiv address = 4.884
set node 0 routing phaseiv prefix = 49::
set node 0 routing dna address format true
set node 0 routing default eshello timer 600
enable node 0 routing
create node 0 routing circuit csmacd-0 type = csma-cd
set node 0 routing circuit csmacd-0 data link entity = csma-cd station csmacd-0
set node 0 routing circuit csmacd-0 enable phaseiv address = false
enable node 0 routing circuit csmacd-0
create node 0 routing circuit fddi-0 type = fddi
set node 0 routing circuit fddi-0 data link entity = fddi station fddi-0
set node 0 routing circuit fddi-0 enable phaseiv address = true
enable node 0 routing circuit fddi-0

The primary function of the Routing layer is to identify the best path to a given destination. DECnet Phase V systems have multiple mechanisms to determine such a path. Under most circumstances, these mechanisms work automatically without any need for special configuration. This section describes the routing mechanisms and explains how to use them to handle special circumstances.

DECnet-Plus uses the following rules in order of precedence to determine where to send each packet:

1. If the destination has a routing circuit inactive area address attribute set for the circuit, DECnet-Plus sends the message over the indicated circuit using the Null Internet format ( Section 8.4.3.4).
2. If the route is explicitly defined in a routing circuit reachable address attribute, DECnet-Plus sends the packet to the indicated destination ( Section 8.4.3.5).
3. If the DECnet-Plus system recently communicated with a given destination, the paths to that destination are saved in the end node cache. DECnet-Plus uses one of the cached paths ( Section 8.4.3.3).
4. If adjacent routers are known to exist on any of the attached circuits, DECnet-Plus sends the message to one of the routers ( Section 8.4.3.1).
5. If the destination is within the sender's area, DECnet-Plus broadcasts the message to all endnodes on all attached LANs.

DECnet Phase IV and Phase V end systems and routers regularly advertise their existence on their attached data links. DECnet-Plus nodes listen for these advertisements and automatically build (autoconfigure) an adjacency database. For LANs, the adjacency database contains the list of routers attached to each circuit. For WAN circuits, the adjacency database identifies the type of node attached to the other end of the circuit, router or endnode. DECnet-Plus also automatically records OSI systems from other vendors in its adjacency database as OSI-only nodes.

If the routers in a subnetwork do not adhere to the DECnet Phase V routing protocol (in other words, they are non-DNA routers), DECnet Phase V end systems are unable to create physical connections to them.

Normally, a DECnet Phase V end system learns about its routers through the ES-IS protocol. If your LAN has only routers that do not implement the ES-IS protocol, you must identify the LAN address of the routers that the DECnet Phase V end system uses. Included in the following sequence of commands is a command needed for specifying the LAN address for a CSMA-CD data link. The command is called out ((1)).

ncl> create routing type endnode
ncl> enable routing

ncl> create routing circuit csmacd-0 -
_ncl> type csmacd

ncl> set routing circuit csmacd-0 manual routers -
_ncl> { 08-00-2b-00-01-03, 08-00-2b-00-03-04 } (1)

ncl> set routing circuit csmacd-0 -
_ncl data link entity csma-cd station csmacd-0

ncl> enable routing circuit csmacd-0

1. This command identifies the LAN address of the routers that the DECnet Phase V end system uses. You can specify up to five routers in this command line.

Displaying Adjacencies

Display routing adjacencies by using the following NCL command:

ncl> show routing circuit circuit_name adjacency * all

The following example shows two adjacencies for circuit csmacd-0:

$ mc ncl show routing circuit csmacd-0 adj * all

Node 0 Routing Circuit CSMACD-0 Adjacency RTG$0001
at 1996-07-24-09:48:29.181-04:00I22.051

Identifiers

    Name                              = RTG$0001

Status

    Type                              = Autoconfigured (1)
    State                             = Up
    LAN Address                       = 08-00-2B-A2-08-B9
    Neighbor Node Type                = Phase V Router (2)
    Router NETs                       =
       {
          47:24:02-01-0A-04:08-00-2B-A2-08-B0:00 ,
          49::00-04:AA-00-04-00-F5-13:00 (DEC:.LKG.LKISL2)
       }


Node 0 Routing Circuit CSMACD-0 Adjacency RTG$0002
at 1996-07-24-09:48:29.191-04:00I22.051

Identifiers

    Name                              = RTG$0002

Status

    Type                              = Autoconfigured
    State                             = Up
    LAN Address                       = AA-00-04-00-FF-13 (LOCAL:.A04NIS)
    Neighbor Node Type                = Phase V Router
    Router NETs                       =
       {
          47:24:02-01-0A-04:08-00-2B-A0-17-90:00 ,
          49::00-04:AA-00-04-00-FF-13:00 (LOCAL:.A04NIS)
       }

1. The adjacency type attribute can be autoconfigured or manual. An autoconfigured adjacency is one that was configured automatically by means of hello PDUs. A manual adjacency is one that was created manually, such as by the create command.
2. The neighbor node type attribute indicates whether the neighboring node is a DECnet Phase V router or a Phase IV router.

Connectivity from a DECnet Phase V end system to a Phase IV node through a router that does not support Phase IV backward compatibility is not possible. A non-DNA OSI router does not know how to translate a DECnet Phase V address to a Phase IV address, or convert Network layer data protocol data unit (PDU) formats. The following are possible solutions to consider:

• Replace the non-DNA routers with routers that understand both DECnet Phase V and Phase IV backward compatibility. If the final destination is a Phase IV end node, the router converts the OSI PDU to a Phase IV PDU that the Phase IV end node can understand and respond to.
• Obtain one DECnet Phase V router and set up static routes on the non-DNA routers to route all data with Phase IV style NSAPs to the DECnet Phase V router. The DECnet Phase V router performs the Phase IV backward compatibility function that the non-DNA OSI router is unable to do.
• On a LAN with both routers that support Phase IV backwards compatibility and routers that do not support Phase IV backwards compatibility, set up the end systems in segregated mode. See Section 8.4.1.3 for details.
• You can also consider the following alternative:
  If the end system does not require connections to a Phase IV node, configure the end system to perform only the OSI protocol. To operate as an OSI-only node, do not set a Phase IV address. However, you may still need to set the Phase IV prefix. For further information on the Phase IV prefix, see Section 8.4.1.5.

If you have configured your DECnet-Plus end systems to have a Phase IV-compatible address and you are operating in a non-DNA environment, you must ensure that all level 2 non-DNA OSI routers advertise the complete set of area addresses for the level 1 networks to guarantee connectivity between your DECnet-Plus end systems.

8.4.3.3 End System Cache

The Routing module stores information about remote systems (including NSAP addresses) to which data transfer is in progress. This information is known as the end system cache, and the data stored in this cache allows the Routing layer to quickly choose the correct data link address to which packets should be forwarded, as well as which format (Phase IV or OSI) should be used. The cache entries are created automatically, based upon the receipt of data and/or routing redirect packets, and indicate if the remote system is on-LAN (direct), or reachable by way of a router (indirect or reverse).

When an end system communicates to another node for the first time, the end system cache has no routing information for that node. The end system chooses at random an adjacent router and transmits the data to it, allowing the adjacent router to find a path to the destination node. The end system creates cache entries based on information about the routing path received from incoming data sent by routers and from advertisements sent directly from other end systems.

Cache entries are each assigned a precedence which determines the path chosen when two or more cache entries refer to the same destination. The Routing module assigns precedence as shown in Table 8-5, where 1 is the highest precedence. Direct reachability indicates the path is direct from source to destination without intermediary routers. Indirect indicates the path is through one or more intermediary routers. Reverse reachability implies the directness of the path is indeterminate at the time (whether a direct path exists will be resolved during subsequent communications).

A reverse path cache entry indicates that a data packet was received from an adjacent node on a specific circuit. The adjacent node could be the original sender or the last router that forwarded the packet. Given no other information, the most efficient path for sending response packets is usually the path the original data message followed.

The Routing module follows these rules for making a cache entry:

• If an entry for a destination NSAP address with higher precedence already exists (on any circuit), no cache entry is made.
• If any entries for a destination NSAP address with lower precedence already exist on any circuit, they are deleted from the cache and a new cache entry is created.
• If an entry for a destination NSAP address with the same precedence exists on the same circuit and with the same datalink address (and any type), the remaining fields in the cache entry are updated.

When multiple paths with the same precedence exist for the same destination, the Routing module selects the path based on round robin. This helps balance the load on the paths. On multicircuit end systems, if no direct path to the destination node exists on a broadcast circuit, a duplicate packet is sent periodically, as determined by the probe rate.

The es cache holding time attribute determines how long an entry is held in the end system cache. The default is 600 seconds. The timer is refreshed each time a data packet is successfully received by the destination node over the path defined by the entry. The entry is deleted if no communication occurs between the source and destination nodes within the period defined by the timer. This maximizes the effectiveness of the end system cache.

Displaying Cache Entries

Cache entries are visible as network management entities known as routing destination cache.

On OpenVMS systems, use the System Dump Analyzer (SDA) to show cache entries, as in the following example:

$ analyze/system

OpenVMS (TM) VAX System Analyzer

SDA> net show routing cache
%SDA-I-READSYM, reading symbol table  SYS$COMMON:[SYSEXE]NET$SYMBOLS.STB;1


DECnet-Plus for OpenVMS Routing ES Cache Dump
--------------------------------------------

%SDA-I-READSYM, reading symbol table  SYS$COMMON:[SYS$LDR]NET$ROUTING_ES.STB;1
Routing Prefix DataBase Address 816C63A8
Prefix Table Start: 825D5F0C , End: 825D610C, Size 0

Routing Cache DataBase Address 816C6390
Cache Table Start: 825D10CC , End: 825D12CC, Size 1
    Cache Entry at Address 825D256C
        NSAP:
                      4900 04AA0004 007F1321
            OSI Transport - (4.895)
        Cache Circuit Entry Count : 1,  Probe Count: 992
        Cache Circuit List: 8260B500
        Cache Circuit Entry:
            Type:                 BroadCast
            Format:               PhaseV
            Reachability:         Direct
            Blocksize:            Non-FDDI
            Remaining LifeTime:   005F
            Holding Time:         0258
            Data Link Address:
                               137F 000400AA ª.....           00000000
                (4.895)

SDA>

DECnet-Plus supports the inactive subset of CLNS, also known as null internet. An inactive subset PDU contains no Network layer addressing information; it is sent directly to the data link address derived from the destination NSAP address. Therefore, it cannot be routed by an intermediate system. This means that only LAN devices can support the inactive subset PDU, and the two communicating nodes must be on the same LAN. The inactive subset of CLNS allows communication with OSI systems that only implement the inactive subset.

Configuring CLNS with null internet is no different from configuring full CLNS, with the following restrictions:

• The routing circuit entity must have its type attribute set to csma-cd.
• You must specify a value for the inactive area address attribute of the routing circuit entity. For inactive area address, each LAN circuit that supports null internet must specify a different inactive area address. (For circuits using only CLNS/ES-IS, this attribute is an empty set (this is the default value).)

For more information on configuring CLNS OSI transport to use the null internet, see Section 8.5.2.4.3.

You can turn the ability to transmit and receive inactive subset protocol data units (PDUs) on and off on a per circuit basis by defining a value for the circuit attribute inactive area address. The following example uses the default inactive area address attribute on a LAN:

ncl> create routing circuit csmacd-0 -
_ncl> type csma-cd

ncl> set routing circuit csmacd-0 -
_ncl> inactive area address {49::FF-00}

ncl> enable routing circuit csmacd-0

You must do this after the circuit is created, but before you enable it. The value is the address of an otherwise unused area in your network.

If you want to change the transport, modify the Routing module's preset attribute, inactive selector, with the selector of the transport you want to use. Only one transport may use the inactive subset and, by default, this is OSI transport (which has a default selector value of 33). To operate NSP over the inactive subset, before enabling the Routing module (and any circuits) enter the command:

ncl> set routing inactive selector 32

When using the inactive subset, destination NSAPs must contain the inactive area address followed by the data link address of the remote machine followed by the transport selector. For example:

49::FF-00:08-00-23-00-01-02:21

Reachable addresses allow the system manager to override the automatic routing mechanisms in DECnet-Plus. You can define reachable addresses for each circuit. Two types of reachable addresses are outbound and filter, as described below. (For information about reachable addresses used for OSI transport over X.25 CONS circuits, see Section 8.8.3.1.)

• Outbound (the default) --- Defines the destination datalink address for packets whose destination NSAP address start with the specified address prefix. If a packet's destination NSAP matches multiple reachable address entities, the one with the longest address prefix is used. Outbound reachable addresses are supported on broadcast circuits and X.25 dynamically assigned circuits. Outbound reachable addresses are necessary to transmit packets directly to nodes in other routing domains.
• Filter --- Reachable addresses of this type are for broadcast circuits only and specify the permitted LAN addresses of routers on the LAN. Only those routers with LAN addresses that are listed in the permitted LAN addresses attribute (described below) will be used for transmitting packets before the routing circuit establishes its reverse path cache.

You can use NCL to switch from the default (outbound) to filter by setting the reachable address entity type attribute to the value filter. You must disable the routing reachable address entity before changing the value of the type attribute.

The following reachable address attributes are supported by outbound reachable addresses:

• data format format, where format is either phase v (the default) or phase iv. This attribute specifies the PDU data format to be used when forwarding data network protocol data units (NPDUs) using this reachable address.
• block size size, where size can be in the range of 0 (the default) to 65535. This attribute defines the data link block size to be used for this prefix. If the block size is set to the default, the manual block size of the circuit will be used instead.
• lan address xx-xx-xx-xx-xx-xx, where xx-xx-xx-xx-xx-xx specifies the single LAN address to which an NPDU may be directed in order to reach an address that matches the address prefix of the parent reachable addressentity. The default value is 00-00-00-00-00-00. You must specify a valid LAN address. This attribute applies to broadcast circuits only.

The following example shows how to use NCL commands to create an outbound type of reachable address:

ncl> create routing circuit csmacd-0 reachable address to-area4 -
_ncl> address prefix 49::00-04:

ncl> set routing circuit csmacd-0 reachable address to-area4 -
_ncl> mapping manual

ncl> set routing circuit csmacd-0 reachable address to-area4 -
_ncl> type outbound

ncl> set routing circuit csmacd-0 reachable address to-area4 -
_ncl> data format phaseiv

ncl> set routing circuit csmacd-0 reachable address to-area4 -
_ncl> block size 500

ncl> set routing circuit csmacd-0 reachable address to-area4 -
_ncl> lan address aa-00-04-00-xx-xx

The permitted lan addresses attribute applies to filter reachable addresses for broadcast circuits only. This attribute specifies a set of LAN addresses corresponding to routers that are permitted to forward to this prefix. The default is an empty set. You must specify at least one LAN address. Specify these LAN addresses within a pair of braces, separating the addresses by commas, as in the last command in the following example, which shows how to create a filter reachable address.

ncl> create routing circuit csmacd-0 reachable address to-area4 -
_ncl> address prefix 49::00-04:

ncl> set routing circuit csmacd-0 reachable address to-area4 -
_ncl> mapping manual

ncl> set routing circuit csmacd-0 reachable address to-area4 -
_ncl> type filter

ncl> set routing circuit csmacd-0 reachable address to-area4 -
_ncl> data format phasev

ncl> set routing circuit csmacd-0 reachable address to-area4 -
_ncl> permitted lan address {aa-00-04-00-xx-xx, aa-00-04-00-yy-yy}