8.7.4 AUTOGEN を実行するためのコマンド・ファイルの作成 |
 |
以下のサンプル・ファイルに示すように，UETP ではコンピュータが最初にクラスタに追加されるときに，そのコンピュータで実行される典型的なユーザ負荷を指定できます。 UETP を実行すると，フィードバック付きでコンピュータをリブートするときに，AUTOGEN がそのコンピュータの適切なシステム・パラメータ値を設定するのに必要なデータが生成されます。しかし，UETP のユーザ負荷のデフォルト設定では，コンピュータがタイムシェアリング・システムとして利用されると想定されています。この計算では，シングル・ユーザ・ワークステーションにとっては大きすぎるシステム・パラメータ値が求められる可能性があります。特に，ワークステーションに大きなメモリ・リソースが搭載されている場合は，計算される値が大きくなりすぎます。したがって，サンプル・ファイルに示すように，ユーザ負荷のデフォルト設定を変更しなければならない可能性があります。
以下の操作を行います。
- 以下のようなコマンド・ファイルを作成します。
$!
$! ***** SYS$COMMON:[SYSMGR]UETP_AUTOGEN.COM *****
$!
$! For initial boot only, run UETP LOAD phase and
$! reboot with AUTOGEN feedback.
$!
$ SET NOON
$ SET PROCESS/PRIVILEGES=ALL
$!
$! Run UETP to simulate a user load for a satellite
$! with 8 simultaneously active user processes. For a
$! CI connected computer, allow UETP to calculate the load.
$!
$ LOADS = "8"
$ IF F$GETDVI("PAA0:","EXISTS") THEN LOADS = ""
$ @UETP LOAD 1 'loads'
$!
$! Create a marker file to prevent resubmission of
$! UETP_AUTOGEN.COM at subsequent reboots.
$!
$ CREATE SYS$SPECIFIC:[SYSMGR]UETP_AUTOGEN.DONE
$!
$! Reboot with AUTOGEN to set SYSGEN values.
$!
$ @SYS$UPDATE:AUTOGEN SAVPARAMS REBOOT FEEDBACK
$!
$ EXIT
|
- クラスタの共通 SYSTARTUP ファイルを編集し，ファイルの最後に以下のコマンドを追加します。キューがすでに起動されていて，新たに追加されたコンピュータでバッチ・キューが実行されているものと仮定しています。 UETP_AUTOGEN.COM をコンピュータのローカル・バッチ・キューに登録します。
$!
$ NODE = F$GETSYI("NODE")
$ IF F$SEARCH ("SYS$SPECIFIC:[SYSMGR]UETP_AUTOGEN.DONE") .EQS. ""
$ THEN
$ SUBMIT /NOPRINT /NOTIFY /USERNAME=SYSTEST -
_$ /QUEUE='NODE'_BATCH SYS$MANAGER:UETP_AUTOGEN
$ WAIT_FOR_UETP:
$ WRITE SYS$OUTPUT "Waiting for UETP and AUTOGEN... ''F$TIME()'"
$ WAIT 00:05:00.00 ! Wait 5 minutes
$ GOTO WAIT_FOR_UETP
$ ENDIF
$!
|
注意: UETP は，SYSTEST というユーザ名のもとで実行しなければなりません。
- CLUSTER_CONFIG_LAN.COM または CLUSTER_CONFIG.COM を実行して，コンピュータを追加します。
コンピュータをブートすると，UETP_AUTOGEN.COM が実行されて，指定したユーザ負荷がシミュレートされ，次にフィードバック・オプション付きで AUTOGEN を実行してリブートが行われ，適切なシステム・パラメータ値が設定されます。
